COBOL言語の「EXTERNAL句」とファイルの外部属性について｜用語辞典

COBOL(コボル)言語の予約語EXTERNAL句を使った命令文の書き方とは

辞典・辞書-EXTERNAL-イメージ

COBOL(コボル)言語のEXTERNAL句とは？

EXTERNAL句は、データ名やファイル名に外部属性を指定して、プログラム間で共用するときに使用します。ファイル記述項（FD）又は作業場所節のレコード記述項に記述することで、ファイルやデータを共用できます。また、ファイルやデータを共用するプログラムでは、ファイルとレコードの定義は完全に同一に記述する必要があります。

書き方1:ファイルに外部属性を指定する

FD [ファイル項目] IS EXTERNAL.

プログラム1:

辞典・辞書-EXTERNAL-プログラム１

プログラム2:

辞典・辞書-EXTERNAL-プログラム２

書き方2：データ項目に外部属性を指定する

01 [データ項目] PIC 99 EXTERNAL.

EXTERNAL句のCOBOL(コボル)言語における基本事項やルールについて

ファイル項目 IS EXTERNAL.などの各要素間における空白や改行有無は自由に設定できます。
ファイルをEXTERNAL句で指定する場合は、ファイル記述項（FD）に指定します。
データをEXTERNAL句で指定する場合は、作業場所節のレコード記述項に指定します。
EXTERNAL句を指定したデータ項目は、レベル番号が01のデータ記述項のみ記述ができます。
EXTERNAL句を指定したファイル数は、最大で255ファイルまでの範囲となります。
EXTERNAL句を指定したデータ領域は、最大で32,767までのデータ領域の範囲となります。
EXTERNAL句を指定した複数のプログラムは、別々のコンパイル単位であっても構いません。

COBOL(コボル)言語のEXTERNAL句を扱う上での注意点

EXTERNAL句を指定したレベル番号01のデータ項目は、別のEXTERNAL句で指定したレベル番号01のデータ項目名と重複してはいけません。
EXTERNAL句を指定したファイルとレコードの定義は、複数のプログラム間で完全に同一に記述する必要があります。差異があった場合はエラーになります。
EXTERNAL句を指定したデータ記述項、またはデータ記述項に従属するデータ記述項にVALUE句を指定することはできません。
ファイル数（255）またはデータ領域（32,767）が上限を超えた場合はエラーとなります。

EXTERNAL句を使ったCOBOL(コボル)プログラムの活用法

以下にEXTERNAL句を使用して、複数のプログラムでファイルを共用する簡単なサンプルプログラムを紹介します。

使用例:SAMPLEPG.cob

IDENTIFICATION           DIVISION.
PROGRAM-ID.              SAMPLEPG.
 
ENVIRONMENT              DIVISION.
  INPUT-OUTPUT SECTION.
     FILE-CONTROL.
        SELECT TEST-FILE ASSIGN TO 'test.txt'
          ORGANIZATION IS LINE SEQUENTIAL.
 
DATA                     DIVISION.
  FILE                   SECTION.
    *>外部ファイルとして指定する
    FD TEST-FILE IS EXTERNAL.
    01 TEST-RECORD-1.
      03 TEST-ITEM-1     PIC X(50).
 
  WORKING-STORAGE        SECTION.
 
PROCEDURE                DIVISION.
  MAIN                   SECTION.
 
  OPEN OUTPUT TEST-FILE.
 
  CALL "SUBPG01".
  CALL "SUBPG02".
 
  CLOSE TEST-FILE.
 
  STOP RUN.

使用例:SUBPG01.cob

IDENTIFICATION           DIVISION.
PROGRAM-ID.              SUBPG01.
 
ENVIRONMENT              DIVISION.
  INPUT-OUTPUT SECTION.
    FILE-CONTROL.
       SELECT TEST-FILE ASSIGN TO 'test.txt'
         ORGANIZATION IS LINE SEQUENTIAL.
 
DATA                     DIVISION.
  FILE                   SECTION.
    *>外部ファイルとして指定する
    FD TEST-FILE IS EXTERNAL.
    01 TEST-RECORD-1.
      03 TEST-ITEM-1       PIC X(50).
 
  WORKING-STORAGE        SECTION.
 
PROCEDURE                DIVISION.
 
  MOVE "SUBPG01 This is an EXTERNAL write test." TO TEST-RECORD-1.
  WRITE TEST-RECORD-1.
 
  DISPLAY "SUBPG01:FILE WRITE"
 
  GOBACK.
 
EXIT PROGRAM.

使用例:SUBPG02.cob

IDENTIFICATION           DIVISION.
PROGRAM-ID.              SUBPG02.
 
ENVIRONMENT              DIVISION.
  INPUT-OUTPUT SECTION.
    FILE-CONTROL.
      SELECT TEST-FILE ASSIGN TO 'test.txt'
        ORGANIZATION IS LINE SEQUENTIAL.
 
DATA                     DIVISION.
  FILE                   SECTION.
    *>外部ファイルとして指定する
    FD TEST-FILE IS EXTERNAL.
    01 TEST-RECORD-1.
      03 TEST-ITEM-1     PIC X(50).
 
  WORKING-STORAGE        SECTION.
 
PROCEDURE               DIVISION.
 
  MOVE "SUBPG02 This is an EXTERNAL write test." TO TEST-RECORD-1.
  WRITE TEST-RECORD-1.
 
  DISPLAY "SUBPG02:FILE WRITE"
 
  GOBACK.
 
EXIT PROGRAM.