COBOLプログラムのパターンを学ぼう！「1対1のマッチング処理」｜応用ガイド

COBOL(コボル)言語の1対1のマッチング処理とは

応用-MATCH1-イメージ

COBOL(コボル)言語の「1対1のマッチング処理」とは？

例えば社員の基本情報を持つマスターファイルがあるとします。このマスターファイルは社員番号がキーとなっており他の社員番号とは重複しないファイルになります。次にトランザクションファイルを考えてみます。

例えば社員が2025年に取得した資格情報を持つファイルがあるとします。このトランザクションファイルも社員番号がキーとなっています。このように同じユニークな社員番号をレコードとして持つファイル同士のマッチング処理を1対1のマッチング処理と言います。では早速プログラムを作成してみましょう。

COBOL(コボル)言語の「1対1のマッチング処理」の処理構成

今回用意したサンプルプログラムの説明をします。このサンプルプログラムは、マスターファイルとトランザクションファイルをそれぞれ読み込み、マッチングキーとして6桁の社員番号を比較していくというプログラムになります。

①社員番号がマッチした場合は、In01のマスターファイルの「社員番号とマッチ」したことがわかるようにメッセージを出力します。その後、次のIn01のレコードを読み込んで再度マッチング処理を行います。

②社員番号がアンマッチの場合は、In01のマスタ?ファイルの「社員番号とアンマッチ」したことがわかるようにメッセージを出力します。その後、次のIn02のレコードを読み込んで再度マッチング処理を行います。

1対1のマッチング処理はこのように①②の処理を繰り返した後、In01のマスターファイルのレコードが読めなくなった場合に処理を終了させます。

使用例：

応用-1対1のマッチング処理を使用したプログラム1-使用例

※マスターファイルとトランザクションファイルはそれぞれキー項目でユニークなレコードになっており、キー項目でソートされている事が前提の処理になっています。

In01.txt
応用-1対1のマッチング処理を使用したプログラム1-入力ファイル1

In02.txt
応用-1対1のマッチング処理を使用したプログラム1-入力ファイル2

実行結果：
応用-1対1のマッチング処理を使用したプログラム1-実行結果1

COBOL(コボル)「1対1のマッチング処理」の応用的な使い方

1対1のマッチング処理の基本的な処理構成と使い方について理解いただけたでしょうか。今度は、応用的な使い方について考えていきましょう。先程ご紹介したサンプルプログラムはIN01のマスターファイルを更新する処理はありませんでしたが、一般的な業務プログラムでは定期的にマスターファイルを更新していることが少なくありません。

今回は1対1のマッチング処理の後にIn02トランザクションファイルの2025年の資格取得数をIn01マスターファイルの資格数に加算して新しいマスターファイル（Out01）を作成するというプログラムを作ってみましょう。しっかり内容を理解して実際のプログラム作成に活用いただければと思います。

サンプルプログラム：

IDENTIFICATION          DIVISION.
PROGRAM-ID.                MATCH11_SAMPLE02.
ENVIRONMENT                DIVISION.
INPUT-OUTPUT               SECTION.
FILE-CONTROL.
 SELECT IN01-FILE
    ASSIGN TO "in01.txt"
    ORGANIZATION IS LINE SEQUENTIAL.
 SELECT IN02-FILE
    ASSIGN TO "in02.txt"
    ORGANIZATION IS LINE SEQUENTIAL.
 SELECT OUT01-FILE
    ASSIGN TO "out01.txt"
    ORGANIZATION IS LINE SEQUENTIAL.
DATA                       DIVISION.
FILE                       SECTION.
FD  IN01-FILE.
01  IN01.
 03  IN01-KEY              PIC X(06).
 03  IN01-SHIKAKU-SU         PIC 99.
FD  IN02-FILE.
01  IN02.
 03  IN02-KEY              PIC X(06).
 03  IN02-SHIKAKU-SU2025     PIC 9.
FD  OUT01-FILE.
01  OUT01.
 03  OUT01-KEY             PIC X(06).
 03  OUT01-SHIKAKU-SU        PIC 99.
WORKING-STORAGE             SECTION.
01  SW-AREA.
 03  SW-IN01-END           PIC  X(01).
01  CST-AREA.
 03  CST-1X                PIC  X(01)  VALUE  '1'.
PROCEDURE                   DIVISION.
*> -------------------------------------------
MATCH-RTN                  SECTION.
*>  初期処理
    PERFORM  INIT-RTN.
*>  主処理
    PERFORM  MAIN-RTN
        UNTIL  SW-IN01-END  =  CST-1X.
*>  終了処理
    PERFORM  END-RTN.
    STOP RUN.
MATCH-EXIT.
*> -------------------------------------------
*>  1.初期処理（ファイルオープン）
INIT-RTN                      SECTION.
  OPEN  INPUT  IN01-FILE.
  OPEN  INPUT  IN02-FILE.
  OPEN  OUTPUT  OUT01-FILE.
  PERFORM  READ01-RTN.
  PERFORM  READ02-RTN.
INIT-EXIT.
*> -------------------------------------------
*>  2.ファイル読み込み処理（IN01）
READ01-RTN                    SECTION.
*>  入力ファイルＲＥＡＤ
  READ  IN01-FILE           AT  END
    DISPLAY "READ IN01 END"
    MOVE  CST-1X            TO  SW-IN01-END
    GO  TO  READ01-EXIT
  END-READ.
READ01-EXIT.
*> -------------------------------------------
*>  ３.ファイル読み込み処理（IN02）
READ02-RTN                    SECTION.
*>  入力ファイルＲＥＡＤ
  READ  IN02-FILE           AT  END
    MOVE  HIGH-VALUE        TO  IN02-KEY
    GO  TO  READ02-EXIT
  END-READ.
READ02-EXIT.
*> -------------------------------------------
*>  ４.主処理（マッチング処理）
MAIN-RTN                      SECTION.
 IF IN01-KEY = IN02-KEY
 THEN
  MOVE IN01-KEY TO OUT01-KEY
  COMPUTE OUT01-SHIKAKU-SU = IN01-SHIKAKU-SU + IN02-SHIKAKU-SU2025
  WRITE  OUT01
  PERFORM  READ01-RTN
 ELSE
  IF IN01-KEY < IN02-KEY
  THEN
    MOVE IN01 TO OUT01
    WRITE  OUT01
    PERFORM  READ01-RTN
  END-IF
  IF IN01-KEY > IN02-KEY
    PERFORM  READ02-RTN
  END-IF
 END-IF.
MAIN-EXIT.
*> -------------------------------------------
*>  ５.終了処理（ファイルクローズ）
END-RTN                       SECTION.
  CLOSE  IN01-FILE.
  CLOSE  IN02-FILE.
  CLOSE  OUT01-FILE.
END-EXIT.
*> -------------------------------------------
END PROGRAM MATCH11_SAMPLE02.